************************************************************************* 
      ** 
      ** Source File Name = rebind.sqb 
      ** 
      ** Licensed Materials - Property of IBM 
      ** 
      ** (C) COPYRIGHT International Business Machines Corp. 1995, 2000  
      ** All Rights Reserved. 
      ** 
      ** US Government Users Restricted Rights - Use, duplication or 
      ** disclosure restricted by GSA ADP Schedule Contract with IBM Corp. 
      ** 
      ** 
      ** PURPOSE: This program is shows how to rebind a package using the 
      **          sqlgrbnd API. 
      ** 
      ** 
      ** APIs USED : 
      **       REBIND                 sqlgrbnd() 
      ** 
      ** For more information about these samples see the README file. 
      ** 
      ** For more information on Programming in COBOL, see the: 
      **    -  "Programming in COBOL" section of the Application Development Guide. 
      ** 
      ** For more information on Building COBOL Applications, see the: 
      **    - "Building COBOL Applications" section of the Application Building Guide. 
      ** 
      ** For more information on the SQL language see the SQL Reference. 
      ** 
      ************************************************************************* 

       Identification Division.
       Program-ID. "rebind".

       Data Division.
       Working-Storage Section.

           copy "sqlenv.cbl".
           copy "sqlca.cbl".
           copy "sqlutil.cbl".

           EXEC SQL BEGIN DECLARE SECTION END-EXEC.
       01 statement         pic x(127).
       01 userid            pic x(8).
       01 passwd.
         49 passwd-length   pic s9(4) comp-5 value 0.
         49 passwd-name     pic x(18).

       01 package.
         49 package-length  pic s9(4) comp-5 value 0.
         49 package-name    pic x(18).
           EXEC SQL END DECLARE SECTION END-EXEC.

       77 rc                  pic s9(9) comp-5.
       77 errloc              pic x(80).

       Procedure Division.
       Main Section.
           display "Sample COBOL program: REBIND".

           display "Enter your user id (default none): " 
              with no advancing.
           accept userid.

           if userid = spaces
              EXEC SQL CONNECT TO sample END-EXEC
           else
              display "Enter your password : " with no advancing.
              accept passwd-name.

      * Passwords in a CONNECT statement must be entered in a VARCHAR format 
      * with the length of the input string. 
           inspect passwd-name tallying passwd-length for characters
              before initial " ".

           display "Enter in the package name : " with no advancing.
           accept package-name.

           inspect package-name tallying package-length for characters
              before initial " ".

           EXEC SQL CONNECT TO sample USER :userid USING :passwd
               END-EXEC.
           move "CONNECT TO" to errloc.
           call "checkerr" using SQLCA errloc.

      ******************* 
      * REBIND PACKAGE  * 
      ******************* 
           call "sqlgrbnd" using
                                 by value     package-length
                                 by reference package-name
                                 by reference sqlca
                                 by value 0
                          returning rc.

           move "Rebinding Package" to errloc.
           call "checkerr" using SQLCA errloc.

           display "Package ", package-name , " has been rebound".
           display "Rolling back the transaction".

           EXEC SQL ROLLBACK END-EXEC.
           move "rollback" to errloc.
           call "checkerr" using SQLCA errloc.

           EXEC SQL CONNECT RESET END-EXEC.
           move "CONNECT RESET" to errloc.
           call "checkerr" using SQLCA errloc.
       End-Main.
           go to End-Prog.

       End-Prog.
           stop run.