QUESTION
 The high level qualifier I use at development is different from the
 one I use at runtime.  How can I change it for runtime ?

ANSWER

 In order to create a database query in VisualAge, you need to specify
 a database access set.  The database access set is a Smalltalk class
 that contains information about your queries.  In particular, the
 private class method DB_allSpecs contains this information.  You
 can manually change this method to specify the new high level
 qualifier, or you can (modify) and run the code below to
 change the method.

 If you created your database query using the SQL Editor (non-manual
 option), the SQL Editor will not show this change.  Consequently,
 if you update your query at a later time, we will generate DB_allSpecs
 with the old high level qualifier.  Remember to modify the method or
 run the code below again.

 Once you've changed the high level qualifier in the DB_allSpecs
 method, we will look for the new high level qualifier at development
 time (test option on the Composition Editor) and runtime.
 The best approach is to have one version of the class for development
 and one for runtime (if you have VisualAge Team).  Make sure to
 release the correct version to your application before packaging it
 for runtime OR create yourself a development and a runtime application
 with the appropriate class.

 " this code will change a high level qualifier for all
   database access sets in an application "

 | app oldHLQ uOldHLQ newHLQ uNewHLQ aSet uStmt oStmt
   aChanges sChanges start index |

 app := yourApp.                "set this to the app you want altered "
 oldHLQ := 'oldHLQ'.            "set this to the old high level qualifier"
 newHLQ := 'newHLQ'.         "set this to the new high level qualifier"
 uOldHLQ := oldHLQ asUppercase.
 uNewHLQ := newHLQ asUppercase.
 ( AbtDbmSystem accessSetNamesForApp: app )
      do: [:aClassName| aChanges := false.
         Transcript cr; show: ( 'Examining Access Set - ',aClassName ).
         ( aSet := aClassName abrAsClass ) registeredQuerySpecs
         do: [:aQuerySpec| oStmt := aQuerySpec statement.
              uStmt := oStmt asUppercase.
              sChanges := false.
              start := 1.
              [( index := uStmt indexOfSubCollection: uOldHLQ startingAt:
                         start ) ~= 0 ]
                 whileTrue: [ oStmt := ( oStmt copyFrom: 1 to: index - 1),
                     newHLQ,
                     ( oStmt copyFrom: index + oldHLQ size to: oStmt size).
                     sChanges := true .
                     uStmt := oStmt asUppercase.
                     start := index + newHLQ size.
                     ].
              ( sChanges )
                 ifTrue: [ aQuerySpec statement: oStmt.
                     aSet putQuerySpec: aQuerySpec.
                     Transcript cr; show:
                          ( 'Changes made to Query Spec - '
                            ,aQuerySpec name ) ].
         ]. " end query specs for access set "
      ]. "end access sets "