/*REXX*/ 
/**********************************************************************/
/* EXEC:      BPXWBRED                                                */
/* PROPRIETARY STATEMENT:                                             */
/*            LICENSED MATERIALS - PROPERTY OF IBM                    */
/*            THIS MODULE IS "RESTRICTED MATERIALS OF IBM"            */
/*            5655-068 (C) COPYRIGHT IBM CORP. 1993,1995              */
/*            SEE COPYRIGHT INSTRUCTIONS                              */
/* STATUS:    HOM1120                                                 */
/* FUNCTION:  Front end to the OpenMVS edit and browse dialogs.       */
/*            This should have aliases of OEDIT and OBROWSE.          */
/* CHANGE ACTIVITY: (recent only)                                     */
/*   $P1=PL70634  HOM1110, 930131, PDND: allow quoted pathname        */
/*   $P2=PL70750  HOM1110, 930514, PDND: use select to handle ATTN    */
/*   $01=OY08318  HOM1120, 940920, PDND: inherit libdef/altlib        */
/*   $xx=xxxxxxx  xxxxxxx, 981010, PDND: f80 edit                     */
/**********************************************************************/
parse arg parm
parse source . . mac .              /* get name of this macro         */
if sysvar(sysispf)<>'ACTIVE' then   /* if ispf not active             */
   do                               /* start it and exec this command */
   address tso 'ispstart cmd('mac parm') newappl(isr)'
   return
   end
address ispexec 'VGET (ZAPPLID)'
if zapplid='ZAPPLID' then           /* this happens from OMVS command */
   do
   address ispexec "SELECT CMD("mac arg(1)")",
          "NEWAPPL(ISR) NEWPOOL PASSLIB"                       /* @01C*/
   return
   end
if pos('EDIT',mac)>0 then           /* set pgm name to call           */
    do
    pnl='BPXWEED'
    pgm='BPXWEDIT'
    end
 else
    do
    pnl='BPXWBBR'
    pgm='BPXWBRWS'
    end
if pos('EDITF',mac)>0 then
   recl=80
 else
   recl=''
if length(parm)>1 then              /*                            @P1A*/
   if substr(parm,1,1)="'" &,       /*                            @P1A*/
       substr(parm,length(parm))="'" then /*                      @P1A*/
      parm=strip(substr(parm,2,length(parm)-2)) /*                @P1A*/
    else 
      do 
      parse var parm ln nm
      if datatype(ln,'W') then
         do
         recl=ln
         parm=strip(nm)
         end
      end
do until parm<>''                   /* loop with panel if no parm     */
   if parm='' then
      do 
      address ispexec "DISPLAY PANEL("pnl")"
      if rc<>0 then
         return
      end
    else 
      do 
      ix=lastpos('/',parm);         /* find last /                    */
      if ix=0 then                  /* if no / in name                */
         do
         hfscwd='.'                 /* assume current dir             */
         hfsname=parm               /* anything on parm is filename   */
         end
       else                         /* if / found                     */
         do
         hfscwd=substr(parm,1,ix)   /* what comes before is dir       */
         hfsname=substr(parm,ix+1)  /* what comes after is file       */
         end
      if hfsname='' then
         do
         parm=''
         iterate
         end
      end
   address ispexec
   'VPUT (HFSCWD HFSNAME)'          /* set shared vars                */
   'CONTROL DISPLAY REFRESH'
   'SELECT CMD('pgm recl')'         /* call pgm                   @P2C*/
   if rc>4 then parm=''
end